开机启动项严重影响系统启动时间,开机后约2分钟内我都不敢开始操作,以为这是杀软360拨号程序……都在排队加载,要是操作急了,很容易死机,但是为了正常使用电脑,必须开机时加载一些程序.但是如果能让他们按一定顺序打开,并设置延时,应该会很好,比如QQ往往会比拨号程序先加载,必定失败,还得自己重登. 至于杀软和360安全卫士,我更希望它们不是开机后马上加载,如果我已经把浏览器打开了,它们再偷偷地打开,岂不很妙?输入法也不是开机后马上就用,也可以事后偷偷加载,也好让我提前就开始正常操作电脑,减少等待时间.
我一直在用一个很简单的脚本，保存为 ***.vbs 就行了。添加到启动文件夹或放在桌面，随便怎样都行。
Dim Wsr
Set Wsr = WScript.CreateObject("WScript.Shell")
'下面表示延迟启动的时间，单位毫秒。
WScript.Sleep(1000)
Wsr.Run """F:\系统工具\Process Explorer\procexp.exe""",,False
WScript.Sleep(2000)
Wsr.Run "D:\tool\nircmd\nircmd.exe inetdial 'ADSL'",0,False
WScript.Sleep(3000)
Wsr.Run """C:\Program Files\xplorer2\xplorer2.exe""",2,False
Set Wsr = NoThing
'结束指定进程
'KillProcess("xxxx")
WScript.quit
'Run 解释
'第一个参数
'程序路径，包含空格时外面是三个引号。
'第二个参数
'0 隐藏窗口并激活另一窗口。
'1 激活并显示一个窗口。若窗口是最小化或最大化，则恢复到其原来的大小和位置。
'2 激活窗口并以最小化显示该窗口。
'3 激活窗口并以最大化显示该窗口。
'4 按窗口最近的大小和位置显示。活动窗口保持活动。
'5 以当前大小和位置激活并显示窗口。
'6 最小化指定窗口并激活按 Z 序排序的下一个顶层窗口。
'7 最小化显示窗口。活动窗口保持活动。
'8 以当前状态显示窗口。活动窗口保持活动。
'9 激活并显示窗口。若窗口是最小化或最大化，则恢复到原来的大小和位置。在还原应用程序的最小化窗口时，应指定该标志。
'第三个参数
'True 等待程序结束或中止后再继续执行后面的脚本。
'False 直接执行后面的脚本。自动延迟启动用这个。
Function KillProcess(NameorPID)
Dim oWMI, oProcs, regEx, oProc
Set oWMI = GetObject("winmgmts:\\.\root\cimv2")
'查询语句，WHERE 后判断进程名是否存在进程中！
If IsNumeric(NameOrPID) Then
Set oProcs = oWMI.ExecQuery("SELECT * FROM Win32_Process WHERE Handle='" & NameOrPID & "'")
Else
Set regEx = New RegExp
regEx.IgnoreCase = True
regEx.Global = True
regEx.Pattern = "/.+\.(com|exe)$/"
If regEx.Test(NameOrPID) Then
Set oProcs = oWMI.ExecQuery("SELECT * FROM Win32_Process WHERE Name='" & NameOrPID & "'")
Else
Set oProcs = oWMI.ExecQuery("SELECT * FROM Win32_Process WHERE Name='" & NameOrPID & ".exe'")
End If
Set regEx = Nothing
End If
'终止上面查询到的进程
For Each oProc in oProcs
oProc.Terminate
Next
Set oProc = NoThing
Set oProcs = NoThing
Set oWMI = NoThing
End Function
